home *** CD-ROM | disk | FTP | other *** search
/ No Fragments Archive 12: Textmags & Docs / nf_archive_12.iso / MAGS / SOURCES / ATARI_SRC.ZIP / atari source / DSHJ2 / FASTROT.SSS < prev    next >
Encoding:
Text File  |  2001-02-10  |  11.0 KB  |  593 lines
  1. *
  2. *
  3. *   Rotate 90 degrees clockwise a large rectangular page-size form in place
  4. *   where the DST form width is less than the SRC form
  5. *
  6. *   Programmer: Dave Staugas
  7. *         Date: 9-June-89
  8. *
  9. *
  10. *   Paper size data:                    Timings (secs):
  11. *                    Temp buf size:   5k  10k  20k  40k
  12. *     Port_width   Land_width   Rectangle excess  d2= 1    2    4    8
  13. *     ----------   ----------   ----------------
  14. *  Letter  300        398       98             56   35   25   20
  15. *  Legal   300        510       210            123   71   45   32
  16. *  A4       292        424       132             72   43   29   22
  17. *  B5       252        366       114             47   30   20   16
  18. *
  19. *
  20.     .globl    roto
  21.     .globl    recrot
  22. *
  23. *
  24. *   Entry:
  25. *
  26. *   a0   -> base address of landscape form to rotate
  27. *   a1   -> temp buffer allocated in multiples of (16 * DST form-width)
  28. *   d0.w =  SRC form-width in bytes (must be even)
  29. *   d1.w =  DST form-width in bytes (must be even)
  30. *   d2.w =  # of (16 * DST form-width) multiples that can be used in temp buffer
  31. *
  32. *   Exit:
  33. *
  34. *   all registers preserved, rectangular form is rotated in place
  35. *        90 degrees clockwise with new (DST) form-width
  36. *
  37. recrot:
  38.     movem.l    a0-a6/d0-d7,-(sp)
  39. *
  40. *  1st rotate largest chunk (a square) in place
  41. *
  42.     move.w    d1,d4        ;do a square rotate 1st
  43.     bsr    roto        ;rotate the biggest chunk in place
  44. *
  45. *  Now rotate-copy d2.w vertical columns of tiles to temp buffer
  46. *
  47.     move.l    a1,a5        ;save temp buf ptr in a5
  48.     lea    (a0,d1.w),a2    ;a2-> SRC top tile of column just rite of square
  49.     lea    -2(a1,d1.w),a3    ;a3-> DST top/rightmost tile of temp buf
  50. schlp:
  51.     move.w    d0,d7        ;d0 = SRC wrap
  52.     lsl.w    #4,d7        ;d7 = SRC tile wrap
  53. *
  54.     move.w    d1,d6        ;d1 = DST wrap
  55.     lsl.w    #4,d6        ;d6 = DST tile wrap
  56. *
  57.     move.l    a2,a4        ;save a2 for later
  58.     move.w    d1,d4        ;DST width
  59.     lsr.w    #1,d4
  60.     subq.w    #1,d4        ;d4 = # of tiles in column (-1)
  61.     subq.w    #1,d2        ;d2 = # of columns (-1)
  62. buflp0:
  63.     movem.l    a2-a3/d2/d4/d6,-(sp)
  64. buflp:
  65.     move.l    a2,a1
  66.     move.l    a3,a6
  67.     bsr    rot2tile
  68.     adda.w    d7,a2
  69.     subq.l    #2,a3    
  70.     dbra    d4,buflp
  71.  
  72.     movem.l    (sp)+,a2-a3/d2/d4/d6
  73.     addq.l    #2,a2
  74.     adda.w    d6,a3
  75.     dbra    d2,buflp0
  76. *
  77.     move.l    8(sp),d2    ;restore buffer size multiple
  78.     add.w    d2,d2        ;  in words
  79. *
  80. *   buffer is full, now scrunch the big form (decrease SRC width by d2*2 bytes)
  81. *
  82.     move.l    a4,a3        ;1st DST column just right of big square
  83.     lea    (a3,d2.w),a2    ;1st SRC column just right of copied columns
  84.     move.w    d1,d4
  85.     lsl.w    #3,d4        ;DST width *8 is # of rows
  86.     move.w    d4,d7
  87.     subq.w    #2,d7
  88. *
  89.     sub.w    d2,d0        ;new SRC width (it's shrinking)
  90.     move.w    d0,d4
  91.     lsr.w    #2,d4        ;get # of long words in SRC row
  92.     bcc.s    elong        ;br if integral # of longwords
  93. *
  94. *   else, do one short word 1st..
  95. *
  96. rwlp0:
  97.     move.w    d4,d5
  98.     move.w    (a2)+,(a3)+
  99.     bra.s    rwlp1i
  100. rwlp1:
  101.     move.l    (a2)+,(a3)+
  102. rwlp1i:
  103.     dbra    d5,rwlp1
  104.     adda.w    d2,a2
  105.     dbra    d7,rwlp0
  106.     bra.s    rwdone
  107. elong:    
  108.     move.w    d4,d5
  109.     bra.s    rwlp2i
  110. rwlp2:
  111.     move.l    (a2)+,(a3)+
  112. rwlp2i:
  113.     dbra    d5,rwlp2
  114.     adda.w    d2,a2
  115.     dbra    d7,elong
  116. rwdone:
  117.     move.w    d0,d7
  118.     sub.w    d1,d7
  119.     lsr.w    #1,d7
  120.     bra    rwlp5i            ;gotta get special case
  121. rwlp5:
  122.     move.w    (a2)+,(a3)+        ;copied for inner column difference
  123. rwlp5i:
  124.     dbra    d7,rwlp5
  125. *
  126. *
  127.     move.w    d1,d6        ;d1 = DST wrap
  128.     lsl.w    #4,d6        ;d6 = DST tile wrap
  129. *
  130. scrnchlp:
  131.     lea    (a0,d0.w),a2    ;a2-> SRC top tile column at far right 
  132.     lea    -2(a3,d1.w),a3    ;a3-> DST rightmost tile of space just freed
  133. *
  134. * 
  135.     move.w    d0,d7        ;d0 = SRC wrap
  136.     lsl.w    #4,d7        ;d7 = tile wrap
  137. *
  138.     sub.w    d2,d0        ;new SRC width (it's shrinking)
  139.     cmp.w    d1,d0        ;did we go too far?
  140.     bpl.s    .10        ;br if ok
  141. *
  142.     move.w    d1,d3
  143.     sub.w    d0,d3        ;d3 = # of word-columns not to do
  144.     sub.w    d3,d2        ;d2 = # of word-columns to do
  145.     add.w    d3,d0
  146.     lsr.w    #1,d3        ;d2 = # of columns not done this trip
  147.     mulu    d6,d3
  148.     add.l    d3,a3        ;adjust DST ptr
  149. .10:
  150.     add.w    d2,d0
  151.     suba.w    d2,a2        ;adjust SRC ptr
  152. *
  153.     move.l    a2,a4        ;save a2 for later
  154.     move.w    d1,d4        ;DST width
  155.     lsr.w    #1,d4
  156.     subq.w    #1,d4        ;d4 = # of tiles in column (-1)
  157.     move.w    d2,-(sp)
  158.     lsr.w    #1,d2
  159.     subq.w    #1,d2        ;d2 = # of columns (-1)
  160. bufloop0:
  161.     movem.l    a2-a3/d2/d4/d6,-(sp)
  162. bufloop:
  163.     move.l    a2,a1
  164.     move.l    a3,a6
  165.     bsr    rot2tile
  166.     adda.w    d7,a2
  167.     subq.l    #2,a3    
  168.     dbra    d4,bufloop
  169. *
  170.     movem.l    (sp)+,a2-a3/d2/d4/d6
  171.     addq.l    #2,a2
  172.     adda.w    d6,a3
  173.     dbra    d2,bufloop0
  174. *
  175.     move.w    (sp)+,d2
  176. *
  177. *   now scrunch the big form (decrease SRC width by d2 bytes)
  178. *
  179.     sub.w    d2,d0
  180.     move.l    a4,a3        ;1st DST to holding buffer
  181.     lea    (a3,d2.w),a2    ;1st SRC column just right of big square
  182.     move.w    d1,d4
  183.     lsl.w    #3,d4        ;DST width *8 is # of rows
  184.     move.w    d4,d7
  185.     subq.w    #2,d7
  186. *
  187.     move.w    d0,d4
  188.     lsr.w    #2,d4        ;get # of long words in SRC row
  189.     bcc.s    evnlong        ;br if integral # of longwords
  190. *
  191. *   else, do one short word 1st..
  192. *
  193. rowlp0:
  194.     move.w    d4,d5
  195.     move.w    (a2)+,(a3)+
  196.     bra.s    rowlp1i
  197. rowlp1:
  198.     move.l    (a2)+,(a3)+
  199. rowlp1i:
  200.     dbra    d5,rowlp1
  201.     adda.w    d2,a2
  202.     dbra    d7,rowlp0
  203.     bra.s    rowdone
  204. evnlong:    
  205.     move.w    d4,d5
  206.     bra.s    rowlp2i
  207. rowlp2:
  208.     move.l    (a2)+,(a3)+
  209. rowlp2i:
  210.     dbra    d5,rowlp2
  211.     adda.w    d2,a2
  212.     dbra    d7,evnlong
  213. rowdone:
  214.     cmp.w    d0,d1            ;have we become DST form-width?
  215.     bne    scrnchlp        ;iterate until we are DST
  216. *
  217. *   Now copy buffer to last freed area
  218. *
  219. *    a3-> DST tile area just freed
  220. *
  221.     move.l    a5,a2        ;get buffer copied back in
  222. *
  223.     lsl.w    #3,d0        ;DST wrap *8 is # of words in buffer
  224.     mulu    8+2(sp),d0
  225.     bra.s    bufini
  226. bufinlp:
  227.     move.w    (a2)+,(a3)+
  228. bufini:
  229.     dbra    d0,bufinlp
  230. *
  231.     movem.l    (sp)+,a0-a6/d0-d7
  232.     rts
  233. *
  234. *   Rotate 90 degrees clockwise a large square page-size form in place
  235. *
  236. *   Programmer: Dave Staugas
  237. *         Date: 5-June-89
  238. *
  239. *   Entry:
  240. *
  241. *   a0   -> base address of square form to rotate
  242. *   d0.w =  form-width in bytes (must be even)
  243. *   d4.w =  # of bytes on a side of the square (also must be even)
  244. *
  245. *   Exit:
  246. *
  247. *  all regs preserved, square form is rotated in place 90 degrees clockwise
  248. *
  249. roto:
  250.     movem.l    a0-a6/d0-d7,-(sp)
  251.     move.w    d0,d7        ;copy form-width to d7
  252.     lsl.w    #4,d7        ;x16 for offset in form for 1 tile down
  253. *
  254.     lsr.w    #1,d4        ;d4 = # tiles on a side
  255. *
  256. *   a2 -> top/left tile address
  257. *
  258. *   d0 = form-wrap
  259. *   d4 = # of tiles on a side
  260. *   d7 = offset in form for 1 tile down
  261. *
  262. rotlp0:
  263.     move.l    a0,a2        ;a2 -> top/left tile
  264.     move.w    d4,d3
  265.     subq.w    #1,d3
  266.     mulu    d7,d3
  267.     lea    (a2,d3.l),a4    ;a4 -> bot/left tile
  268.     add.w    d4,d4
  269.     lea    -2(a2,d4.w),a3    ;a3 -> top/right tile
  270.     lea    -2(a4,d4.w),a5    ;a5 -> bot/right tile
  271.     lsr.w    #1,d4
  272. rotlp1:
  273.     move.l    a2,a1        ;top/left is SRC
  274.     moveq    #2,d1        ;DST form wrap (just 16 byte buffer)
  275.     lea    tilebuf,a6
  276.     bsr    rot2tile    ;rotate top/left to buffer
  277. *
  278.     move.l    a4,a1        ;bot/left is SRC
  279.     move.w    d0,d1        ;DST form wrap is same as SRC
  280.     move.l    a2,a6        ;top/left is DST
  281.     bsr    rot2tile    ;rotate bot/left to top/left tile
  282. *    
  283.     move.l    a5,a1        ;bot/right is SRC
  284.     move.l    a4,a6        ;bot/left is DST
  285.     bsr    rot2tile    ;rotate bot/right to bot/left tile
  286. *
  287.     move.l    a3,a1        ;top/right is SRC
  288.     move.l    a5,a6        ;bot/right is DST
  289.     bsr    rot2tile    ;rotate top/right to bot/right
  290. *
  291.     lea    tilebuf,a1
  292.     move.l    a3,a6
  293.     moveq    #15,d5
  294. coploop:
  295.     move.w    (a1)+,(a6)
  296.     adda.w    d0,a6
  297.     dbra    d5,coploop    ;copy rotated tile buffer to top/left
  298. *
  299.     adda.w    d7,a2        ;move top/left down 1 tile
  300.     suba.w    d7,a5        ;move bot/right up 1 tile
  301.     addq.l    #2,a4        ;move bot/left right 1 tile
  302.     subq.l    #2,a3        ;move top/right left 1 tile
  303.     cmp.l    a0,a3        ;does top/right equal base?
  304.     bne    rotlp1        ;iterate until it does
  305. *
  306.     lea    2(a0,d7.w),a0    ;now put base down 1 tile & left 1 tile
  307.     subq.l    #2,d4        ;next # of tiles on a side
  308.     beq.s    rotdone        ;br if none left
  309.     cmpi.w    #1,d4        ;check for odd case
  310.     bne    rotlp0
  311. *
  312.     move.l    a0,a1
  313.     move.l    a0,a6
  314.     bsr    rot2tile
  315. *
  316. rotdone:
  317.     movem.l    (sp)+,a0-a6/d0-d7
  318.     rts
  319. *
  320. *
  321. *
  322. *
  323. *    
  324. ******************************************
  325. *
  326. *   Rotate a 16x16 pixel tile clockwise 90 degrees and copy to another tile
  327. *
  328. *
  329. *   d0 = SRC form-wrap
  330. *   d1 = DST form-wrap
  331. *
  332. *   a1 -> top/left of SRC tile
  333. *   a6 -> top/left of DST tile
  334. *  
  335. rot2tile:
  336.     movem.l    a0/a2-a5/d0-d1/d4/d7,-(sp)
  337. *
  338. *  pack 16 words of tile into 4 data & 4 address registers..
  339. *
  340.     move.w    (a1),d2
  341.     adda.w    d0,a1
  342.     move.w    (a1),d3
  343.     adda.w    d0,a1
  344.     move.w    (a1),d4
  345.     adda.w    d0,a1
  346.     move.w    (a1),d5
  347.     adda.w    d0,a1
  348. *
  349.     swap    d2
  350.     swap    d3
  351.     swap    d4
  352.     swap    d5
  353. *
  354.     move.w    (a1),d2
  355.     adda.w    d0,a1
  356.     move.w    (a1),d3
  357.     adda.w    d0,a1
  358.     move.w    (a1),d4
  359.     adda.w    d0,a1
  360.     move.w    (a1),d5
  361.     adda.w    d0,a1
  362. *
  363.     exg    d2,a2
  364.     exg    d3,a3
  365.     exg    d4,a4
  366.     exg    d5,a5
  367. *
  368.     move.w    (a1),d2
  369.     adda.w    d0,a1
  370.     move.w    (a1),d3
  371.     adda.w    d0,a1
  372.     move.w    (a1),d4
  373.     adda.w    d0,a1
  374.     move.w    (a1),d5
  375.     adda.w    d0,a1
  376. *
  377.     swap    d2
  378.     swap    d3
  379.     swap    d4
  380.     swap    d5
  381. *
  382.     move.w    (a1),d2
  383.     adda.w    d0,a1
  384.     move.w    (a1),d3
  385.     adda.w    d0,a1
  386.     move.w    (a1),d4
  387.     adda.w    d0,a1
  388.     move.w    (a1),d5
  389. *
  390. *   Got all 16 words of tile in registers, now rotate..
  391. *
  392.     moveq    #3,d0        ;iterate 4 times
  393. rotlp2:
  394.     swap    d1        ;DST form-width to high word
  395.     swap    d0        ;get d0.w ready to receive bits
  396.     add.w    d5,d5
  397.     addx.w    d1,d1
  398.     add.w    d5,d5
  399.     addx.w    d0,d0
  400.     add.w    d5,d5
  401.     addx.w    d6,d6
  402.     add.w    d5,d5
  403.     addx.w    d7,d7
  404.  
  405.     add.w    d4,d4
  406.     addx.w    d1,d1
  407.     add.w    d4,d4
  408.     addx.w    d0,d0
  409.     add.w    d4,d4
  410.     addx.w    d6,d6
  411.     add.w    d4,d4
  412.     addx.w    d7,d7
  413.  
  414.     add.w    d3,d3
  415.     addx.w    d1,d1
  416.     add.w    d3,d3
  417.     addx.w    d0,d0
  418.     add.w    d3,d3
  419.     addx.w    d6,d6
  420.     add.w    d3,d3
  421.     addx.w    d7,d7
  422.  
  423.     add.w    d2,d2
  424.     addx.w    d1,d1
  425.     add.w    d2,d2
  426.     addx.w    d0,d0
  427.     add.w    d2,d2
  428.     addx.w    d6,d6
  429.     add.w    d2,d2
  430.     addx.w    d7,d7
  431. *
  432.     swap    d2
  433.     swap    d3
  434.     swap    d4
  435.     swap    d5
  436. *
  437.     add.w    d5,d5
  438.     addx.w    d1,d1
  439.     add.w    d5,d5
  440.     addx.w    d0,d0
  441.     add.w    d5,d5
  442.     addx.w    d6,d6
  443.     add.w    d5,d5
  444.     addx.w    d7,d7
  445.  
  446.     add.w    d4,d4
  447.     addx.w    d1,d1
  448.     add.w    d4,d4
  449.     addx.w    d0,d0
  450.     add.w    d4,d4
  451.     addx.w    d6,d6
  452.     add.w    d4,d4
  453.     addx.w    d7,d7
  454.  
  455.     add.w    d3,d3
  456.     addx.w    d1,d1
  457.     add.w    d3,d3
  458.     addx.w    d0,d0
  459.     add.w    d3,d3
  460.     addx.w    d6,d6
  461.     add.w    d3,d3
  462.     addx.w    d7,d7
  463.  
  464.     add.w    d2,d2
  465.     addx.w    d1,d1
  466.     add.w    d2,d2
  467.     addx.w    d0,d0
  468.     add.w    d2,d2
  469.     addx.w    d6,d6
  470.     add.w    d2,d2
  471.     addx.w    d7,d7
  472. *
  473.     swap    d2
  474.     swap    d3
  475.     swap    d4
  476.     swap    d5
  477. *
  478.     exg    d2,a2
  479.     exg    d3,a3
  480.     exg    d4,a4
  481.     exg    d5,a5
  482. *
  483. *
  484.     add.w    d5,d5
  485.     addx.w    d1,d1
  486.     add.w    d5,d5
  487.     addx.w    d0,d0
  488.     add.w    d5,d5
  489.     addx.w    d6,d6
  490.     add.w    d5,d5
  491.     addx.w    d7,d7
  492.  
  493.     add.w    d4,d4
  494.     addx.w    d1,d1
  495.     add.w    d4,d4
  496.     addx.w    d0,d0
  497.     add.w    d4,d4
  498.     addx.w    d6,d6
  499.     add.w    d4,d4
  500.     addx.w    d7,d7
  501.  
  502.     add.w    d3,d3
  503.     addx.w    d1,d1
  504.     add.w    d3,d3
  505.     addx.w    d0,d0
  506.     add.w    d3,d3
  507.     addx.w    d6,d6
  508.     add.w    d3,d3
  509.     addx.w    d7,d7
  510.  
  511.     add.w    d2,d2
  512.     addx.w    d1,d1
  513.     add.w    d2,d2
  514.     addx.w    d0,d0
  515.     add.w    d2,d2
  516.     addx.w    d6,d6
  517.     add.w    d2,d2
  518.     addx.w    d7,d7
  519. *
  520. *
  521.     swap    d2
  522.     swap    d3
  523.     swap    d4
  524.     swap    d5
  525. *
  526.  
  527.     add.w    d5,d5
  528.     addx.w    d1,d1
  529.     add.w    d5,d5
  530.     addx.w    d0,d0
  531.     add.w    d5,d5
  532.     addx.w    d6,d6
  533.     add.w    d5,d5
  534.     addx.w    d7,d7
  535.  
  536.     add.w    d4,d4
  537.     addx.w    d1,d1
  538.     add.w    d4,d4
  539.     addx.w    d0,d0
  540.     add.w    d4,d4
  541.     addx.w    d6,d6
  542.     add.w    d4,d4
  543.     addx.w    d7,d7
  544.  
  545.     add.w    d3,d3
  546.     addx.w    d1,d1
  547.     add.w    d3,d3
  548.     addx.w    d0,d0
  549.     add.w    d3,d3
  550.     addx.w    d6,d6
  551.     add.w    d3,d3
  552.     addx.w    d7,d7
  553.  
  554.     add.w    d2,d2
  555.     addx.w    d1,d1
  556.     add.w    d2,d2
  557.     addx.w    d0,d0
  558.     add.w    d2,d2
  559.     addx.w    d6,d6
  560.     add.w    d2,d2
  561.     addx.w    d7,d7
  562. *
  563.     swap    d2
  564.     swap    d3
  565.     swap    d4
  566.     swap    d5
  567. *
  568.     exg    d2,a2
  569.     exg    d3,a3
  570.     exg    d4,a4
  571.     exg    d5,a5
  572. *
  573.     move.w    d1,(a6)
  574.     swap    d1        ;get DST form-width
  575.     adda.w    d1,a6
  576.     move.w    d0,(a6)
  577.     swap    d0        ;get loop count
  578.     adda.w    d1,a6
  579.     move.w    d6,(a6)
  580.     adda.w    d1,a6
  581.     move.w    d7,(a6)
  582.     adda.w    d1,a6
  583. *
  584.     dbra    d0,rotlp2    ;do all 16
  585. *
  586.     movem.l    (sp)+,a0/a2-a5/d0-d1/d4/d7
  587.     rts
  588. *
  589. *
  590.     .bss
  591. tilebuf:
  592.     .ds.w    16
  593.